// 
// Common Utility Routines Library 
//

bool ScriptLib_Flag = true;

void LogF( str Text ) {

  Log("LOG--> " + Text + "<br>" );
  SysLog ( Text );

}

str md5file( str File ) {

  var binmd5 = MD5Create();
  var binfil = LoadFile( File );
  MD5Update( binmd5, binfil, 0, sizeof( binfil ) );
  var md5 = MD5Finish( binmd5 );
  str hexmd5 = BinToHex( md5 );
  return hexmd5;

}

// Rotate files (to save history...)
void RotateFile(str File, int Rotation) {

  int Rotation_1;
  while ( Rotation > 1 ) {
    if (FileExists(File+".saved."+(str)Rotation)) 
        RemoveFile(File+".saved."+(str)Rotation);
    Rotation_1 = Rotation - 1;
    if (FileExists(File+".saved."+(str)Rotation_1)) 
        RenameFile(File+".saved."+(str)Rotation_1,File+".saved."+(str)Rotation);  
    Rotation--;
  }
  if (FileExists(File+".saved.1")) 
      RemoveFile(File+".saved.1");
  if (FileExists(File)) 
      RenameFile(File,File+".saved.1");  

}

bool diff( str File1, str File2 ) {

  if ( md5file( File1 ) != md5file( File2 ) ) 
    return true;
  else 
    return false;

}

void cp( str Source, str Destin ) {

  if ( FileExists( Source ) ) {
    if ( FileExists( Destin ) ) {
      if ( diff( Source, Destin ) ) {
        RotateFile( Destin, SavedVersions );
      } else {
        return;
      }
    }
    FileCopy( Source, Destin );
  } else {
    ShowConsole();
    LogF( "<font color=\"#aa0000\">Error during file copy (cp):<br>Source File "+Source+" not found</font>" );
	delay(600);
  }

}

void mv( str Source, str Destin ) {

  cp ( Source, Destin );
  if ( FileExists( Source ) )
       RemoveFile( Source );

} 


str WOComma(str Text) {
  var TextArray = StrParse( Text, "," );
  str Out = "";
  for (int i=0;i<sizeof(TextArray);i++ ) {
    Out += TextArray[i];
  }
  return Out;
}

int PatchRegistry( str RegPatch, int WinDisk, int WinPart  ) {

  if ( ! FileExists( RegPatch ) ) {
    ShowConsole();
    LogF( "<font color=\"#aa0000\">Patch Registry File: " + RegPatch + " not found</font>" );
    return -1;
  }

  NTDetect();
  
  str NewRegContent;
  str BaseRegister;
  str RegPath = "DISK://" + (str)WinDisk + ":" + (str)WinPart + "/" + NTSystemRoot + "/system32/config/";
  str RegFile;
  str RegName;
  str RegTypeValue;
  str RegType;
  str RegValue;
  str FilArray[];
  str PrevReg = "";
  int NAR;
  int Pos;
  int Pun2;
  int ACapo;
  bool RegOpen_Flag = false;
  var BinValue;
  
  NewRegContent = LoadTextFile( RegPatch );
  
  FilArray = StrParse(NewRegContent,"\r\n");
  
  NAR = sizeof(FilArray);
  if ( FilArray[0] != "REGEDIT4" ) {
    LogF( RegPatch + ": Not a REGEDIT4 File" );
    return -1;
  } else {
    for ( int i=1; i<NAR; i++ ) {
      if ( StrTrim( FilArray[i] ) != "" ) { 
        if ( StrMatch( FilArray[i], "[*]" ) ) {
          FilArray[i] = StrCopy( FilArray[i], 1, sizeof(FilArray[i])-1 );
          str RegArray[];
          RegArray = StrParse( FilArray[i], "\\" );
          if ( RegArray[0] != "HKEY_LOCAL_MACHINE" ) {
            LogF( RegArray[0] + ": Not a HKEY_LOCAL_MACHINE register patch ... skipped");
            return -1;
          }
          if ( RegArray[1] != PrevReg ) {
            if ( RegOpen_Flag ) CloseRegistry( "regis" ); 
            PrevReg = RegArray[1];
            RegFile = (str)RegPath + (str)PrevReg;
            // Log(RegFile);
            OpenRegistry( "regis", RegFile );
            RegOpen_Flag = true;
          }
          BaseRegister = "";
          for ( int j=2;j<sizeof(RegArray);j++ ) {
            BaseRegister += RegArray[j] + "/";
            if ( !FileExists( "reg://regis/" + BaseRegister ) ) {
              MkDir( "reg://regis/" + BaseRegister );
            }
          }
          // LogF(BaseRegister);
        } else {
          Pos = StrFind( FilArray[i], "=" );
          if ( StrMatch( FilArray[i], "*\\") ) {
            ACapo = 1;
          } else {
            ACapo = 0;
          }
  	if ( Pos == -1 ) {
            RegValue += StrTrim( StrCopy( FilArray[i], 0, sizeof(FilArray[i]) - ACapo ) );
          } else {
            RegName = StrTrim( StrCopy( FilArray[i], 0, Pos ) );
  	  RegTypeValue = StrCopy( FilArray[i], Pos+1, sizeof(FilArray[i]) - ACapo );
            if ( StrMatch( RegTypeValue, "dword:*" ) ) {           // Dword value
              Pun2 = StrFind( RegTypeValue, ":" );
              RegValue = StrCopy( RegTypeValue, Pun2+1 , sizeof( RegTypeValue ) );
              RegType = ".dword";
            } else if ( StrMatch( RegTypeValue, "hex:*" ) ) {      // Binary value
              Pun2 = StrFind( RegTypeValue, ":" );
              RegValue = StrCopy( RegTypeValue, Pun2+1 , sizeof( RegTypeValue ) );
              RegType = ".binary";
            } else if ( StrMatch( RegTypeValue, "hex(2):*" ) ) {   // Expand_SZ (expuni) value
              Pun2 = StrFind( RegTypeValue, ":" );
              RegValue = StrCopy( RegTypeValue, Pun2+1 , sizeof( RegTypeValue ) );
              RegType = ".expuni";
            } else if ( StrMatch( RegTypeValue, "hex(7):*" ) ) {   // Multi_SZ (multiuni) value
              Pun2 = StrFind( RegTypeValue, ":" );
              RegValue = StrCopy( RegTypeValue, Pun2+1 , sizeof( RegTypeValue ) );
              RegType = ".multiuni";
            } else {                                               // SZ (unicode) value
              RegValue = StrTrim( RegTypeValue );
              RegType = ".unicode";
            }
  	}
          if ( ACapo == 0 ) { 
            if ( RegType == ".binary" ) {
              RegValue = WOComma( RegValue );
              CreateBinaryFile( "reg://regis/" + BaseRegister + RegName + RegType, BinFromHex( RegValue ) );
            } else if ( RegType == ".dword" ) {
              RegValue = (str)StrCopy( RegValue, 6, 8) + (str)StrCopy( RegValue, 4, 6) + (str)StrCopy( RegValue, 2, 4) + (str)StrCopy( RegValue, 0, 2);
              CreateBinaryFile( "reg://regis/" + BaseRegister + RegName + RegType, BinFromHex( RegValue ) );
            } else if ( RegType == ".expuni" ) {
              RegValue = BinToStr( BinFromHex( WOComma( RegValue ) ) );
              CreateUnicodeFile( "reg://regis/" + BaseRegister + RegName + RegType, RegValue );
            } else if ( RegType == ".multiuni" ) {
              str Strings[];
              var RegHex = StrParse( RegValue, "," );
              int NChar = sizeof(RegHex);
              if ( NChar > 2 ) {
                int mu = 0;
                for ( int i=0; i<NChar-2; i++ ) {
                  if ( RegHex[i] == "00" ) {
                    mu++;
                  } else {
                    Strings[mu] += (str)BinToStr( BinFromHex( RegHex[i] ) );
                  }
                }
              }
              CreateMultiUniFile( "reg://regis/" + BaseRegister + RegName + RegType, Strings );
            } else if ( RegType == ".unicode" ) {
              bool Slash_Flag = false;
              str CopyReg = "";
              int NChar = sizeof(RegValue);
              for ( int i=0; i<NChar; i++ ) {
                str Char1 = StrCopy( RegValue, i, i+1 );
                if ( Char1 == "\\" && ! Slash_Flag ) {
                  Slash_Flag = true;
                } else {
                  Slash_Flag = false;
                  CopyReg += StrCopy( RegValue, i, i+1 );
                }
              }
              RegValue = CopyReg;
              CreateUnicodeFile( "reg://regis/" + BaseRegister + RegName + RegType, RegValue);
            }
            // LogF ((str)i +": "+(str)RegName+(str)RegType+" = "+RegValue);
          }
        }
      }
    }
    if ( RegOpen_Flag ) CloseRegistry( "regis" );
    RegOpen_Flag = false;
    FlushAll();
  }
  return 1;
}